Comparison of Evolution Factors, Collins Evolution compared with Sun - Yun
Used for Aidala, Field, Gamberg, Rogers:  arXiv:1401.2654

Clear["Global *"]
Needs["PlotLegends`"]

Clear[bmax]
C1 = 1.123;
AA = (9/(4 Pi)); (** Parameter for alphaS.  Normalization from 1/beta0 with flavors = 3. Correspond to 1/A in paper. ***)
LamQCD = .2123; (** Parameter for alphaS.  Lambda_QCD.***)
Q0 = Sqrt[2.4];

Matching Prescription:

bstar[bt_,bmax_] := bt/ Sqrt[1 + bt^2 / bmax^2]  (** Prescription for matching to b_max. **)
mub[bt_,bmax_] := C1 / bstar[bt,bmax];

Strong Coupling, approximate fit to Bethke 2009, best for small mu

AlphaS[mu_]:= 1 / (2 AA Log[mu/LamQCD]); 
gK2[bt_,g2_,aa_] :=(aa^2) (g2/2)Log[1 + bt^2 / aa^2]

Perturbative terms in the exponent of the evolution factor in Collins/CSS and Sen - Yuan :

evolfactPDF[Q_,bt_,bmax_] :=(2 / Pi / AA) (Log[Log[Q/LamQCD]/Log[mub[bt,bmax]/LamQCD]] - (4/3) Log[Q/LamQCD](Log[Log[Q/LamQCD]/Log[mub[bt,bmax]/LamQCD]])+ (4/3) Log[Q/mub[bt,bmax]])
evolfactPDF2[Q_,bt_,bmax_,g2_,aa_] :=(2 / Pi / AA) (Log[Log[Q/LamQCD]/Log[mub[bt,bmax]/LamQCD]] - (4/3) Log[Q/LamQCD](Log[Log[Q/LamQCD]/Log[mub[bt,bmax]/LamQCD]])+ (4/3) Log[Q/mub[bt,bmax]]) - 2 gK2[bt,g2,aa] Log[Q/Q0] 
(** Collins TMD Evolution factor without non-perturbative parts.**)

evolfactPDFSY[Q_,bt_] := (-4/ 3 /Pi / AA) ( 2 Log[Q/LamQCD]Log[Log[Q/LamQCD]/Log[Q0/LamQCD]] - 2 Log[Q/Q0]+ (Log[Q0^2 bt^2/C1^2] - 3/2)Log[Log[Q/LamQCD]/Log[Q0/LamQCD]]) 
(** Sen-Yuan TMD Evolution factor. **)

Plot of strong coupling :

LogLinearPlot[AlphaS[mu],{mu,1,100},PlotRange->{0,.5},PlotLabel-> "(Subscript[α, s])", AxesLabel-> {"μ","(Subscript[α, s])"},LabelStyle-> {Large},PlotStyle-> {Thick}]

Plots of evolution terms for Collins and Sun - Yuan respectively :
	Plots are for Q = 2, 5, 10 GeV. 
	For Collins b_max effectively taken to infinity by using b_max = 100 GeV^-1.
	
These should go in the paper. (Figs. 10-11 in arXiv:1401.2654)

Plot[{evolfactPDF[2,bt,100.0],evolfactPDF[5,bt,100.0],evolfactPDF[10,bt,100.0]},{bt,.01,5},PlotRange->{-2,1},PlotLabel-> "Collins TMD-Evolution Factor, No NP Part", AxesLabel-> {"(Subscript[b, T])",""},LabelStyle-> {Large},PlotStyle-> {Thick}]
Plot[{evolfactPDF2[2,bt,0.5,0.1,2.0],evolfactPDF2[5,bt,0.5,0.1,2.0],evolfactPDF2[10,bt,0.5,0.1,2.0]},{bt,.01,5},PlotRange->{-2,1},PlotLabel-> "Collins TMD-Evolution Factor With NP Part", AxesLabel-> {"(Subscript[b, T])",""},LabelStyle-> {Large},PlotStyle-> {Thick}]
Plot[{evolfactPDFSY[2,bt],evolfactPDFSY[5,bt],evolfactPDFSY[10,bt]},{bt,.01,5},PlotRange->{-2,1},PlotLabel-> "Sun-Yuan TMD-Evolution Factor", AxesLabel-> {"(Subscript[b, T])",""},LabelStyle-> {Large},PlotStyle-> {Thick}]